; Successive Division Simulation
; written by Teresa Carrigan, 2004

globals [ start-x from-decimal praise digits myDigits doneyet? ]
breeds [ digit holder divisor rem stack]
digit-own [ digit-value digit-name]
patches-own [ name ]
holder-own [holder-name]
stack-own [stack-name]

;  runs setup when program is first loaded
to startup
  setup
end

;  makes the correct number of digits, and the red arrow
;  initializes variables
to setup
  locals [ here-x here-y current n]
  ca
  set praise [ "You got it!" "Right!" "Correct" "Awesome!" "Perfect!" ]
  set digits [ "0" "1" "2" "3" "4" "5" "6" "7" "8" "9" "A" "B" "C" "D" "E" "F" ]
  set myDigits []
  set n 0
  repeat 10 [
        set myDigits lput (item n digits ) myDigits
        set n (n + 1)
    ]
  set start-x -3
  set here-x -5
  set here-y 6
  set current 1
  set n 0
  set doneyet? false
  ;  build decimal number
  set from-decimal 0
  if base = 2 and number-of-digits = 5
    [set number-of-digits 4 ]
    
  repeat number-of-digits [
        set from-decimal (10 * from-decimal) + random 10
    ]
  cct-divisor 1
      [
        setxy here-x here-y
        set color black
        set size 1
        set label-color green + 2
        set label base
        set here-x here-x + 2
        hideturtle     
      ]
  cct-holder 1
      [
        setxy here-x here-y
        set shape "successive-division"
        set color white
        set size 2
        set holder-name "current"
        set here-x here-x + 1.2
        hideturtle
      ]
  cct-digit 1
      [
        setxy here-x here-y
        set color black
        set size 1
        set label-color cyan + 2
        set digit-value from-decimal
        set label from-decimal
        set here-x here-x + 1
      ]
  
;    create explanation bar at the bottom
    ask patches with [ pycor < -3 ]
        [ set pcolor blue - 2]
    ask patches with [ pycor < -5 ]
        [ set pcolor blue ]
    ask patch-at 6 -6
        [ set plabel "Converting " + from-decimal + " from decimal to base " + base 
          set plabel-color white
          set name 1
        ]
    ask patch-at 6 -7
        [ set plabel "using Successive Division." 
          set name 2
        ]
end

;  randomize settings and start over
to setup-random
  set number-of-digits 2 + (random 4)
  set base 2 + (random 15)
  setup
end

;  decimal equivalent of digit pattern
to-report calc
  locals [ answer x tempList]
  while [ not doneyet?]
    [  go ]
  ask stack with [ member? "=" label]
    [  set answer remove "Answer =" label
       set x xcor
    ]
  set tempList stack with [ xcor > x ]
  while [count tempList > 0]
    [
      ask min-one-of stack with [ xcor > x] [ xcor ]
        [ set x xcor
          set answer (word answer label)
        ]
      set tempList stack with [ xcor > x ]
    ]
  wait .5
  set answer clean-input answer
  report answer
end

;  single division step
to one-step
  locals [ here-x here-y dividend remdr]
  ask holder with [ holder-name = "current" ]
    [
       set here-x xcor
       set here-y ycor
       set holder-name ""
    ]
  
  ask digit with [ ycor = here-y ]
    [
      set dividend label
    ]
  ifelse (dividend > 0) and not doneyet?
    [
      ask holder
        [ showturtle ]
      ask divisor
        [ showturtle ]
      set here-y here-y - 2
      set here-x here-x - 1
    
    cct-divisor 1
        [
        setxy here-x here-y
        set color black
        set size 1
        set label-color green + 2
        set label base
        set here-x here-x + 2     
        hideturtle
        ]
      cct-holder 1
        [
        setxy here-x here-y
        set shape "successive-division"
        set color white
        set size 2
        set holder-name "current"
        set here-x here-x + .75
        hideturtle
        ]
      cct-digit 1
        [
        setxy here-x here-y
        set color black
        set size 1
        set label-color cyan + 2
        set digit-value int (dividend / base)
        set label int (dividend / base)
        set here-x here-x + 1.75
        ]
      cct-rem 1 [
          setxy here-x here-y
          set shape "successive-division"
          set color yellow
          set label-color yellow
          set size 1.4
          set remdr (dividend mod base)
          set label remdr
          ]  
      
      cct-stack 1 [
          setxy here-x here-y
          set shape "circle"
          set color blue - 2
          set label-color yellow
          set label remdr + " "
          set size 2
          set stack-name "moving"
          ]

      ask stack with [ stack-name = "moving" ]
          [ wander-to-stack
          ]

  

      if here-y <= -2
        [ without-interruption [scroll ]]

    ]
    [
      last-step
    ]
   if here-y <= -2
        [ without-interruption [scroll ]]
    
   if (dividend = 0) 
     [ set doneyet? true 
     ]
end

to step-north
  set heading 0
  fd 2
end

to step-west
  set heading -90
  fd 1
end

to scroll
  locals [ n step-up step-left]
  set n ycor-of max-one-of turtles [ ycor ]
  ask turtles with [ ycor = n ]
    [ die ]
  ask digit 
    [ 
      step-north
      step-west
    ]
  ask holder 
    [ step-north
      step-west
    ]
  ask divisor 
    [ step-north
      step-west
    ]
  ask rem 
    [ step-north
      step-west
    ]
end

to wander-to-stack
  locals [ to-x to-y n ]
  set to-x screen-size-x * .4
  set to-y -4.5
  if any? stack with [ stack-name != "moving" ]
    [
      set to-x xcor-of min-one-of stack with [ stack-name != "moving"] [ xcor ]
      set to-x (to-x - 1.5)
    ]
  while [ (ycor != to-y) or (xcor != to-x) ]
    [
      set heading towardsxy-nowrap to-x to-y
      set n (distancexy to-x to-y)
      ifelse n > 1
        [ fd 1 ] 
        [ setxy to-x to-y ]
      wait slow-motion     
    ]
  set stack-name "done"
  set n read-from-string label
  if n > 9
    [set label (word item n digits " ")]
  check-stack
end

to check-stack
  locals [ n num x y ]
  if count stack with [stack-name = "done" ] > 3
    [  set num ""
       ask max-one-of stack with [stack-name = "done" ] [ xcor]
         [  
           set num (word label num)
           set stack-name "three"
         ]
       ask max-one-of stack  with [stack-name = "done" ] [ xcor]
         [  
           set num (word label num)
           die
         ]
       ask max-one-of stack with [stack-name = "done" ] [ xcor]
         [  
           set num (word label num)
           die
         ]
       ask stack with [ stack-name = "three"]
         [
           set label ", " + num
           set stack-name "holdthree"
         ]
       ask stack with [stack-name = "done"]
         [
           set heading 90
           fd 2
         ]
    ]
end

to last-step
  locals [ n num x y ]
  set n count stack with [stack-name = "done" ]
  set num ""
  if n > 0
[  ask max-one-of stack with [stack-name = "done" ] [ xcor]
         [  
           set num (word label num)
           set stack-name "three"
         ]
  if  n > 1
    [  ask max-one-of stack  with [stack-name = "done" ] [ xcor]
         [  
           set num (word label num)
           die
         ]
       if n > 2
       [ask max-one-of stack with [stack-name = "done" ] [ xcor]
         [  
           set num (word label num)
           die
         ]
       ]
    ]
  ]
       ask stack with [ stack-name = "three"]
         [
           set label "Answer = " + num
           set stack-name "holdthree"
         ]
end

;  show remainder of the example
to go
  ifelse  not doneyet? 
    [ one-step 
      wait slow-motion
    ]
    [ last-step
      stop
    ]
end

;  show the same example again
to show-again
  locals [ here-x here-y current n]
  set start-x -3
  set here-x -5
  set here-y 6
  set current 1
  set n 0
  set doneyet? false
  ask turtles [ die ]

  cct-divisor 1
      [
        setxy here-x here-y
        set color black
        set size 1
        set label-color green + 2
        set label base
        set here-x here-x + 2
        hideturtle     
      ]

  cct-holder 1
      [
        setxy here-x here-y
        set shape "successive-division"
        set color white
        set size 2
        set holder-name "current"
        set here-x here-x + 1.2
        hideturtle
      ]

  cct-digit 1
      [
        setxy here-x here-y
        set color black
        set size 1
        set label-color cyan + 2
        set digit-value from-decimal
        set label from-decimal
        set here-x here-x + 1
      ]
  
  ask patches
    [ set plabel "" ]
  explain 1 "Converting " + from-decimal + " from decimal to base " + base 
  explain 2 "using Successive Division." 
end

to explain [ which what ]
  ask patches with [ name = which]
    [ set plabel what ]
end

;  asks the user to convert a number from decimal to a base
to ask-other 
  locals [ guess target question ]
  set question (word from-decimal "")
  set question add-commas question
  set guess user-input (word "Convert the decimal number " question " to base " base ".")
  set guess clean-input guess
  set target calc
  ifelse guess = target 
    [ user-message random-one-of praise ]
    [ user-message "I'm sorry, but the correct answer is " + add-commas target]
end

to-report clean-input [guess]
  locals [ pos k upper lowerList]
  set guess remove " " guess
  set guess remove "," guess
  set lowerList ["a" "b" "c" "d" "e" "f"]
  foreach lowerList
    [
      while [member? ? guess]
        [
          set pos position ? guess
          set k position ? lowerList
          set upper (item (k + 10) digits)
          set upper word upper ""
          set guess replace-item pos guess upper
        ]
    ]
  report guess  
end

;  read the digits, storing it as a string
to-report get-number
  locals [ target n num]
  set target ""
  set n 4
  repeat number-of-digits
    [
      set num label-of random-one-of digit-at n 0
      set target (word num target)
      set n (n - 2)
    ]
  set target remove " " target
  report target
end

;  add commas every three digits, so the user won't make copy errors
to-report add-commas [ number ]
  locals [ save k ]
  set save ""
  set k 0
  while [ (length number) > 0 ]
    [
      set save (word last number save )
      set number butlast number
      set k (k + 1)
      if (k = 3) and (length number > 0)
        [ set save (word "," save )
          set k 0
        ]
    ]
  set number save  
  report number
end

;  ask a quiz question
to quiz
  locals [ save-slow ]
  set save-slow slow-motion
  set slow-motion 0
  without-interruption [setup ]
  wait .5
  ask-other
  set slow-motion save-slow
end

; *** NetLogo Model Copyright Notice ***
;
; Copyright 2004 by Teresa W. Carrigan.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Teresa W. Carrigan.
; Contact Teresa W. Carrigan for appropriate licenses for redistribution 
; for profit.
;
; To refer to this model in academic publications, please use:
; Carrigan, T. (2004).  Horner's Method Simulation model.
; Blackburn College, Carlinville IL.
;
; In other publications, please use:
; Copyright 2004 by Teresa W. Carrigan.  All rights reserved.  
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
3
10
388
466
7
8
25.0
1
18
1
1
1

CC-WINDOW
396
341
589
460
Command Center

BUTTON
417
41
500
74
NIL
setup
NIL
1
T
OBSERVER
T

SLIDER
417
180
589
213
number-of-digits
number-of-digits
2
5
3
1
1
digits

SLIDER
417
145
590
178
slow-motion
slow-motion
0
0.5
0.2
0.05
1
seconds

BUTTON
418
109
500
142
quiz
quiz
NIL
1
T
OBSERVER
T

SLIDER
418
213
590
246
base
base
2
16
8
1
1
NIL

BUTTON
417
75
499
108
step
one-step
NIL
1
T
OBSERVER
T

BUTTON
501
40
590
73
random
setup-random
NIL
1
T
OBSERVER
T

BUTTON
501
74
590
107
go
go
T
1
T
OBSERVER
T

BUTTON
501
109
590
142
NIL
show-again
NIL
1
T
OBSERVER
T

@#$#@#$#@
WHAT IS IT?
-----------
This model demonstrates the successive division method of converting a positive integer from decimal to another base, which is also known as the division-remainder method.  You may choose any base in the range of two to sixteen.


HOW IT WORKS
------------
First the model generates a random decimal number to convert to the specified base.  The next step is to divide the decimal number by the base.  The remainder becomes the right-most digit of the answer.  Step three divides the quotient, again storing the remainder, even if it is zero.  This process continues until the quotient is zero.  The equivalent in the other base will have the same digits as the remainders, with the last remainder being the left-most digit.  If the base is larger than 10, then some remainders will be larger than nine; they will have to be converted to their equivalent single digit character.


HOW TO USE IT
-------------
If you want examples from a specific base:
Use the number-of-digits slider to set the number of digits for the decimal number. Use the  base slider to set the base.  Now press the setup button.  This will generate a random number with that many decimal digits.  If you are converting to base 2, you will not be allowed to have five decimal digits because then the result has too many bits.

If you do not care which base is used, click the random button to generate an arbitrary base, number-of-digits, and number.
  
The slow-motion slider is an easy way to adjust the speed of the display.  Set it to zero if you want to show the final result as quickly as possible.  0.25 is a good setting for most purposes.

The step button does a single division, and copies the remainder to the display at the bottom.  It then stops so you can take notes.  This is useful when you are first learning the method.

The go button continues dividing until the quotient is zero, at a speed determined by the slow-motion slider.  This is useful when you do not need to take notes between each step.

The show-again button starts the exact problem from the beginning.  You may then click either the step button or the go button to see the same demonstration.

The quiz button will generate a random number using the number-of-digits slider, and ask you to convert it to the base on the base slider.  If you want to drill conversion to hexadecimal, set the base to 16 and the number-of-digits to a small number.  


THINGS TO NOTICE
----------------
When the base is smaller than ten, the decimal number will have at most the same number of digits as the converted number, and usually it will have fewer digits.  When the base is larger than ten, the decimal number will have at least the same number of digits as the converted number, and usually it will have more digits.

Successive division is Horner's method in reverse.


THINGS TO TRY
-------------
Set slow-motion to 0.25, click random, and then click go.

Set the sliders to a problem type you want to drill, then click setup.  Attempt one step at a time on paper, and then click the step button to check that you did that step correctly.

EXTENDING THE MODEL
-------------------
Modify the model to show fixed point representation; that is, specify a given number of digits to the right of the decimal place.

Allow the user to input a decimal number, and then display the corresponding digit pattern.

NETLOGO FEATURES
----------------
"ask max-one-of stack with [stack-name = "done" ] [ xcor]" was very useful in finding the right-most turtle of breed stack.  The stack-name was used to indicate the state of the turtle.

"set heading towardsxy-nowrap to-x to-y" was used to guide the remainder to the correct place in the stack at the bottom.

RELATED MODELS
--------------
Horner's Method, Place Value Method, Binary Counter, Counting in Other Number Bases


CREDITS AND REFERENCES
----------------------
This model was written by Teresa W. Carrigan, 2004.  

Permission to use, modify or redistribute this model is hereby granted,
provided that both of the following requirements are followed:
	a) this copyright notice is included.
	b) this model will not be redistributed for profit without permission
	   from Teresa W. Carrigan.
Contact Teresa W. Carrigan for appropriate licenses for redistribution 
for profit.

To refer to this model in academic publications, please use: 
Carrigan, T. (2004). Successive Division Method Simulation model. 
Blackburn College, Carlinville, IL.

In other publications, please use: 
Copyright 2004 by Teresa W. Carrigan.  All rights reserved.  

FOR MORE INFORMATION
--------------------
For more information about successive division, see one of these textbooks:
[1]  Null, L. and Lobur, J. "Essentials of Computer Organization and Architecture", First Edition, Jones and Bartlett, pages 39-41.
[2]  Dale, N. and Lewis, J. "Computer Science Illuminated", Second Edition, Jones and Bartlett, pages 42-43.

@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

successive-division
false
0
Rectangle -7566196 true true 0 0 29 302
Rectangle -7566196 true true 27 269 298 300

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@