; Signed Integer Representation Model 
; written by Crystal Barchet and Teresa Carrigan, 2004 


globals [ from-number from-string number-of-digits start-x myDigits praise digits1 save-base base step ] 
breeds [ digit arrow ] 
arrow-own [ state ]
patches-own [ name ]

; runs the program when it is first loaded
to startup
  setup
end


; initializes variables
to setup
  locals [here-x current n]
  ca
  set praise ["Awesome!" "You got it!" "Right!" "Correct!" "Perfect!" "Bravo!" "Splendid!"]
  set digits1 [ "0" "1" ]
  set base 2
  set save-base base
  set myDigits []  
  set n 0
  set start-x 9
  set here-x 7
  set current 1
  set n 0
  
  repeat 2 [
        set myDigits lput ( item n digits1 ) myDigits
        set n (n + 1)
    ]  
  set n 1
  
  ;  initialize decimal number
  set from-number -32 + random 64
  set from-string (word from-number "")

  if from-number >= 0
    [ set from-string (word "+" from-string) ]
  
  ask patch-at 0 5
    [  set plabel from-string
    ]
  
  ;  create red arrow
  cct-arrow 1 [
    hideturtle
    setxy start-x 0
    set heading -90
    set color red
    set shape "arrow"
    set size 2
    set state 0
  ]
  
  ;  check for random format
  if random-format 
    [ setup-random-format ]
  
; create explanation bar at bottom
ask patches with [ pycor < -3 ]
  [set pcolor blue]
  ask patch-at 6 -4
  [set plabel  (word "Eight-bit " format " of a decimal integer,")
  set plabel-color white
  set name 1
  ]
  ask patch-at 6 -5
  [
    set plabel-color white
    set plabel "starting with " + from-string + " decimal."
    set name 2
  ]
  set step 1
end

  
;  read the digits, storing it as a string
to-report get-number [ howmany ]
  locals [ target n num]
  set target ""
  set n 7
  repeat howmany
    [ if any? digit-at n 0
        [  set num label-of random-one-of digit-at n 0
           set target (word num target)
        ]
      set n (n - 2)
    ]
  set target remove " " target
  report target
end


; adds a space in the number so it can be read easier
to-report add-space [ target ]
  locals [ before after result k ]
  set k length target
  ifelse k > 4
    [  set before substring target 0 4
       set after substring target 4 k
       set result (word before " " after)
    ]
    [  set result target ]
  report result
end



; this is for the bottom explanation
to explain [ which what ]
  ask patches with [ name = which ]
    [ set plabel what ]
end

;  convert from decimal to unsigned binary
to step1
  explain 1 (word "Storing decimal integer " from-number ".")
  explain 2 "Step 1: Temporarily remove the sign."
  wait slow-motion
  ask patch-at -4 4
    [  set name "sign"
       set plabel first from-string
    ]
  ask patch-at 4 4
    [  set name "decimal"
       set plabel but-first from-string
    ]
  set step step + 1
  wait slow-motion
end

to step2
  locals [ num num-string unsigned dividend rem]
  explain 2 "Step 2: Convert to unsigned binary."
  set num-string but-first from-string
  set num read-from-string num-string
  set unsigned ""
  ;  convert
  while [num > 0]
    [
      set dividend int (num / 2)
      set rem (num mod 2)
      set unsigned (word rem unsigned)
      ask patch-at 4 3
        [ set name "unsigned"
          set plabel unsigned
        ]
      set num dividend
      wait slow-motion
    ]
  explain 2 "Unsigned binary representation: " + (add-space unsigned)
  wait slow-motion
  setup-bits unsigned
  set step step + 1
end

; setup the bits
to setup-bits [ unsigned ]
  locals [ here-x ]
  set number-of-digits length unsigned
  set here-x ( start-x - 2)
  repeat number-of-digits
    [
      cct-digit 1
      [ 
        setxy here-x 0
        set shape "circle"
        set color white
        set size 2
        set label-color black
        set label (word (last unsigned)  " ")
      ] ; end cct digits
      set unsigned but-last unsigned
      set here-x (here-x - 2)   
      wait slow-motion
    ]
  
end

;  pad to 8 bits
to step3
locals [ numdig  ]
  explain 2 "Step 3: Pad to eight bits."
  set numdig 8 - number-of-digits
  ask arrow [
        showturtle
        while [state < number-of-digits]
        [
          if any? other-digit-here 
            [ set state state + 1
              set label state + "  "]
          fd 1
          wait slow-motion
        ]    
        fd 1
        wait slow-motion
        repeat numdig 
        [
           hatch 1
            [ 
              set breed digit
              set shape "circle"
              set color white
              set size 2
              set label-color black
              set label  "0 "
             ] ; end cct digits
             
             set state state + 1
             set label state + "  "
             fd 1
             wait slow-motion
             fd 1
             wait slow-motion
             
        ]

    ]
    set step step + 1
end

; if positive, then finished
to step4
  locals [ mySign ]
  explain 2 "Step 4: Check the sign."
  wait slow-motion * 3
  ask patches with [ name = "sign" ]
    [ set mySign plabel ]
  ifelse mySign = "+"
    [ explain 2 "Positive, so we are finished."
      explain 1 (word from-number " decimal = " (add-space get-number 8) " " format " format.")
      set step 10
    ]
    [ explain 2 "Negative, so we are not finished yet."
    ]
  set step (step + 1)
  wait slow-motion
  ask arrow
    [ hideturtle
      set label "" ]
end

;  handle signed magnitude case
to step5
  locals [ ]
  if format = "signed magnitude"
    [ 
      explain 1 "Signed magnitude format and negative number,"
      explain 2 "so just make the left-most bit 1."
      wait slow-motion * 2
      ask min-one-of digit [ xcor ]
        [ set label "1 " 
          set color yellow
        ]
      wait slow-motion
      explain 1 (word from-number " decimal = " (add-space get-number 8) )
      explain 2 (word "using binary signed magnitude format.")
      set step 10
    ]
  set step (step + 1)
  ask arrow [ hideturtle ]
end

;  find one's complement (invert all the bits)
to step6
  explain 1 (word format " and negative number")
  explain 2 "Invert each bit: 1 becomes 0 and 0 becomes 1."
  ask arrow 
  [  showturtle  
     setxy start-x 0
     set state 0
     repeat 18 [
        fd 1
        wait slow-motion
        if any? other-digit-here
          [  flip
             set state state + 1
          ]
       ]
  ]
  explain 2 "Now in one's complement form."
  if format = "one's complement"
    [
      set step 10
      explain 1 (word from-number " decimal = " (add-space get-number 8) )
      explain 2 (word "using one's complement format.")
    ]
  wait slow-motion * 2
  set step step + 1
  ask arrow [ hideturtle ]
end



;  add one to inverted number
to step7
  explain 2 "Add 1 to the inverted number."
  ask arrow [ 
      showturtle
      setxy start-x 0
      wait slow-motion
      fd 2
      increment 
    ]
    set step (step + 1)
end


; the final answer is displayed
to step8
  explain 1 (word from-number " decimal = " (add-space get-number 8) )
  explain 2 (word "using two's complement format.")
  set step 10
  ask arrow [ hideturtle ]
end


;  add one to the bit pattern (arrow specific procedure)
to increment
  wait slow-motion
  ifelse any? other-digit-here
    [ ask other-digit-here
      [  ifelse first label = "0"
          [ set label "1 "
            ask arrow [go-back]
          ]
          [  set label "0 "
             ask arrow [fd 2 increment]
          ]    ; end ifelse
       ]    ; end ask other-digit-here
     ]    ; end then part of ifelse any?
     [  ask arrow [go-back] 
     ]    ; end ifelse any?
end

;  return red arrow to starting position
to go-back
  rt 90
  fd 5
  wait slow-motion
  rt 90
  set xcor start-x
  wait slow-motion
  rt 90
  fd 5
  wait slow-motion
  rt 90
  set state "done" 
end


;  cleans up the user input
to-report clean-input [guess]
  locals [ pos k upper lowerList]
  set guess remove " " guess
  set guess remove "," guess
  report guess  
end


; creates a random quiz quesiton and praise if it is right and says its wrong if it is
to ask-question
  locals [ guess save-slow target]
  set guess user-input (word "What is the eight bit " format " format of " from-number "?")
  set guess (word " " guess " " )
  set guess clean-input guess
  set save-slow slow-motion
  set slow-motion 0
  while [ step < 10 ]
    [  go  ]
  set slow-motion save-slow
  without-interruption [ set target get-number 8]
  ifelse guess = target
    [  user-message random-one-of praise ]
    [  user-message "I'm sorry, but the correct answer is " + add-space target + "."]
end

; sets up a random quiz
to setup-random-format
  set format random-one-of [ "signed magnitude" "one's complement" "two's complement" ]
end

; calls the quiz when the button is pressed
to quiz
  locals [ save-slow ]
  set save-slow slow-motion
  set slow-motion 0
  if random-format
    [ setup-random-format ]      
  without-interruption [setup ]
  wait .5
  ask-question
  set slow-motion save-slow
end


; flips the digits (called by the invert procedure)
to flip
  if any? other-digit-here
    [
      ask other-digit-here
        [  set color yellow
            ifelse first label = "0"
              [  set label "1 " ]
              [  set label "0 " ]
        ]
    ]
end


;  do whatever step comes next, then wait until user wants to continue
to one-step
  locals [ which ]
  if step < 10
    [  set which (word "step" step)
       run which
    ]
end


; this is the go button, that when pressed, goes through remainder of the simulation
to go
  ifelse  step < 10 
    [  one-step
       wait slow-motion
    ]
    [  stop
    ]
end

to show-again
  locals [here-x current n]
  set start-x 9
  set here-x 7
  set current 1
  
  set n 1

  ask turtles [ die ]
  ask patches [ set plabel "" ]
  
  ask patch-at 0 5
    [  set plabel from-string
    ]
  
  ;  create red arrow
  cct-arrow 1 [
    hideturtle
    setxy start-x 0
    set heading -90
    set color red
    set shape "arrow"
    set size 2
    set state 0
  ]
  
  explain 1 (word "Eight-bit " format " of a decimal integer,")
  explain 2 "starting with " + from-string + " decimal."

  set step 1
end

; *** NetLogo Model Copyright Notice ***
;
; Copyright 2004 by Crystal Barchet and Teresa W. Carrigan.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Teresa W. Carrigan.
; Contact Teresa W. Carrigan for appropriate licenses for redistribution 
; for profit.
;
; To refer to this model in academic publications, please use:
; Barchet, C. and Carrigan, T. (2004).  Signed Integer Representation Model.
; Blackburn College, Carlinville, IL.
;
; In other publications, please use:
; Copyright 2004 by Crystal Barchet and Teresa W. Carrigan.  All rights reserved.  
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
13
10
548
316
10
5
25.0
1
18
1
1
1

CC-WINDOW
29
431
566
601
Command Center

BUTTON
13
318
76
351
NIL
setup
NIL
1
T
OBSERVER
T

SLIDER
143
318
315
351
slow-motion
slow-motion
0
1
0.5
0.1
1
NIL

BUTTON
13
351
76
384
step
one-step
NIL
1
T
OBSERVER
T

BUTTON
78
319
141
352
NIL
go
T
1
T
OBSERVER
T

BUTTON
78
352
141
385
quiz
quiz
NIL
1
T
OBSERVER
T

CHOICE
327
319
546
364
format
format
"signed magnitude" "one's complement" "two's complement"
1

SWITCH
327
364
547
397
random-format
random-format
0
1
-1000

BUTTON
143
353
316
386
NIL
show-again
NIL
1
T
OBSERVER
T

@#$#@#$#@
WHAT IS IT?
-----------
This model demonstrates the three formats for storing a signed decimal integer as an pattern of eight bits: signed magnitude, one's complement, and two's complement.

HOW IT WORKS
------------
First, the sign is separated from the decimal digits.  The decimal digits are then converted to unsigned binary, and padded to eight bits.  If the sign is positive, then this is the answer, no matter which format is being used.  When using signed magnitude, a negative number simply changes the left-most bit from a zero to a one.  When using one's complement, a negative number simply inverts each bit.  That is, each one becomes a zero, and each zero becomes a one.  When using two's complement, first the one's complement is determined, and then we add one to get the answer.

HOW TO USE IT
-------------
The setup button generates a random signed decimal integer.

The step button demonstrates the next step, and then stops so you can take notes.  This is useful when you are first learning the method.

The go button does every remaining step, at a speed determined by the slow-motion slider.  This is useful when you do not need to take notes between each step.

The show-again button starts the exact problem from the beginning.  You may then click either the step button or the go button to see the same demonstration.

The slow-motion slider is an easy way to adjust the speed of the display.  Set it to zero if you want to show the final result as quickly as possible.  0.5 is a good setting for most purposes.

If the random-format switch is off, then the format demonstrated is the one selected by the format choice box.  If the switch is on, then a random format will be chosen.

The format choice box allows you to select which format (signed magnitude, one's complement, two's complement) is demonstrated.  The random-format switch must be off for your choice to be used.

The quiz button will generate a random signed decimal integer and ask the user to convert it to either signed magnitude, one's complement, or two's complement.  The format used is determined by the format choice box or the random-format switch.


THINGS TO NOTICE
----------------
The answer will always have eight bits.

Padding is done before inverting or adding one.

If the decimal number is positive, then all three formats give the same bit pattern, and the left-most bit of the answer will be zero.

If the decimal number is negative, then the three formats will give different bit patterns, but in each case the left-most bit of the answer will be one.


THINGS TO TRY
-------------
Set slow-motion to 0.5, select random format, click setup, and then click go.

Set the format to a type you wish to drill, and set random-format off.  Click setup.  Work each step by hand, and then click the step button to check your answer.

EXTENDING THE MODEL
-------------------
Allow the user to input the starting decimal integer.

Calculate and display all three formats for the same decimal integer.

Allow the user to specify either eight-bit or sixteen-bit format.

Allow a larger range for the generated decimal integer, and check for overflow.


NETLOGO FEATURES
----------------
word is used to concatenate inputs together and reports the result as a string. 

one-step uses the NetLogo run command combined with a global integer variable step to run the next step, without needing nested ifelse blocks. 

without-interruption runs all the commands in the block without allowing other agents to "interrupt". That is, other agents are put "on hold" and do not execute any commands until the commands in the block are finished. 


RELATED MODELS
--------------
Binary Counter, Successive Division


CREDITS AND REFERENCES
----------------------
This model was written by Crystal Barchet and Teresa W. Carrigan, 2004.  

Permission to use, modify or redistribute this model is hereby granted,
provided that both of the following requirements are followed:
	a) this copyright notice is included.
	b) this model will not be redistributed for profit without permission
	   from Teresa W. Carrigan.
Contact Teresa W. Carrigan for appropriate licenses for redistribution 
for profit.

To refer to this model in academic publications, please use: 
Barchet C. and Carrigan, T. (2004). Signed Integer Representation Model. 
Blackburn College, Carlinville, IL.

In other publications, please use: 
Copyright 2004 by Crystal Barchet and Teresa W. Carrigan.  All rights reserved.  

FOR MORE INFORMATION
--------------------
For more information on representation of negative integers, see one of the following textbooks:
[1] Null, L. and Lobur, J. "Essentials of Computer Organization and Architecture", First Edition, Jones & Bartlett, pages 44-55. 
[2] Dale, N. and Lewis, J. "Computer Science Illuminated" Second Edition, Jones and Bartlett, page 59-63.

@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@